extends State

@export var max_speed: float = 2.5
@export var acceleration: float = 1.0
@export var deceleration: float = 100.0

@export var toggle: bool = false
@export var stand_up_area: Area3D
@export var player: Player
@export var player_movement: PlayerMovement
@export var player_input: PlayerInput
@export var animation_player: AnimationPlayer
@export var crouch_time: float = 0.1
@export var weapon_system: WeaponSystem

func enter() -> void:
	animation_player.play("crouch",-1,1/crouch_time)
	player_input.crouch_end.connect(try_end_crouch)

func exit() -> void:
	animation_player.play("crouch",-1,-1/crouch_time,true)
	player_input.crouch_end.disconnect(try_end_crouch)

func physics_update(delta: float) -> void:
	if not is_multiplayer_authority():
		return
	
	if not player.is_on_floor():
		transition.emit("Fall")
		return
	
	player_movement.process_movement(max_speed * weapon_system.get_speed_modifier(),acceleration,deceleration,delta)

func try_end_crouch() -> void:
	if player.is_on_floor() and stand_up_area.has_overlapping_bodies() == false:
		transition.emit("Stand")