extends State

@export var max_speed: float = 5.0
@export var acceleration: float = 2.0
@export var deceleration: float = 200.0
@export var JUMP_VELOCITY: float = 4.5
@export var player: Player
@export var player_movement: PlayerMovement
@export var weapon_system: WeaponSystem
@export var audio: MultiplayerAudio3D
@export var step_delay: float
@export var step_speed_curve: Curve

var step_time: float

func enter() -> void:
	pass

func exit() -> void:
	step_time = 0

func physics_update(delta: float) -> void:
	if not is_multiplayer_authority():
		return
	if Input.is_action_just_pressed("plr_jump") and player.is_on_floor():
		player.velocity.y = JUMP_VELOCITY * sign(weapon_system.get_speed_modifier())
		transition.emit("Fall")
		return
	
	if not player.is_on_floor():
		transition.emit("Fall")
		return
	
	step_time += delta * step_speed_curve.sample((player.velocity * Vector3(1,0,1)).length_squared()/(max_speed*max_speed))
	if step_time >= step_delay:
		step_time = 0
		audio.multiplayer_play()
	
	player_movement.process_movement(max_speed * weapon_system.get_speed_modifier(),acceleration,deceleration,delta)

func state_input(event: InputEvent) -> void:
	if event.is_action_pressed("plr_crouch"):
		transition.emit("Crouch")
	
	if event.is_action_pressed("plr_walk"):
		transition.emit("Walk")