project('pacman-raylib','cpp')

incdir = include_directories(['third_party/include','include'])

compiler = meson.get_compiler('cpp')

if host_machine.system() == 'windows'
  raylib_lib = meson.current_source_dir() / 'third_party/lib/windows/libraylib.a'
  
  deps = [
    compiler.find_library('winmm'),
    compiler.find_library('gdi32'),
    compiler.find_library('opengl32'),
    ]
else
  raylib_lib = meson.current_source_dir() / 'third_party/lib/linux/libraylib.a'
  
  deps = [
    compiler.find_library('m'),
    compiler.find_library('dl'),
    compiler.find_library('pthread'),
    compiler.find_library('X11'),
    ]
endif

src_files = [
  'src/atlas.cpp',
  'src/entity.cpp',
  'src/ghost.cpp',
  'src/main.cpp',
  'src/maploader.cpp',
  'src/pacman.cpp',
  'src/scorepoint.cpp',
  'src/wall.cpp',
  'src/world.cpp',
  ]

raylib_dep = declare_dependency(
  include_directories: incdir,
  link_args: raylib_lib,
  dependencies: deps
  )

executable('pacman-raylib',
          files(src_files),
          include_directories: incdir,
          dependencies: [raylib_dep,deps])